true power of MS excel. update: PowerBI

[romcel11]

Re: MS excel formula, programming, analysis, presentation and tutorials.

mejo komplikado pala hahaha.. kala ko simpleng saving lang sa database. Tanong ko lang, yung check ba na sinasabi mo is literal na cheke (image), so pano illink yung data dun sa image?[/Q


excel format lang po. i adjust ko lang na tumama ung mga link data sa check form

wilz, eto na ung new workbook mo

Note: puro built-in excel formula lang gnmit naten dito
1) dun sa database sheet ka mg-eencode ng mga records.
1.a) dapat ung mga formula mai-drag mo pababa.
2) para ma load ung mga details ng cheke gamitin mo
ung print check here na sheet. tapos input mo sa
cell A1 ung record number ng checke na gusto mo iprint.

Goodluck!

 

[wilz1234]

Re: MS excel formula, programming, analysis, presentation and tutorials.

wilz, eto na ung new workbook mo

Note: puro built-in excel formula lang gnmit naten dito
1) dun sa database sheet ka mg-eencode ng mga records.
1.a) dapat ung mga formula mai-drag mo pababa.
2) para ma load ung mga details ng cheke gamitin mo
ung print check here na sheet. tapos input mo sa
cell A1 ung record number ng checke na gusto mo iprint.

Goodluck!

SIR ROMCEL at sa lahat nag contribute sa workbook ko MARAMING SALAMAT PO SA INYONG LAHAT!!More power To u guys!! God bless us all

 

[romcel11]

Re: MS excel formula, programming, analysis, presentation and tutorials.

SIR ROMCEL at sa lahat nag contribute sa workbook ko MARAMING SALAMAT PO SA INYONG LAHAT!!More power To u guys!! God bless us all

wilz, balitaan mo kame kung epektib o kung my mga kulang pa.

 

[gelnee]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Maraming salamat dito

 

[romcel11]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Share ko lang, para sa mga nag-VVBA pero nababagalan sa code nila.

Eto ung code na gngmit ko, Subroutine to na dapat tawagin sa loob ng subroutine nyo.

OPTIMIZE_VBA

Public Sub OPTIMIZE_VBA(ByVal isOn As Boolean, Optional ByRef ExApp As Excel.Application = Nothing)
Dim bHolder As Boolean      '<~ holds an inveresed value of isOn
bHolder = Not isOn          '<~ actually pass the value from isOn
On Error Resume Next        '<~ disables all errors raised

'<~ set ExApp as this Application, ung mismong pinag-lalagyan ng code na to.
'<~ pde kasi nitong i-Disable/Enable ung object ng ibang Excel App.
If IsEmpty(ExApp) Or ExApp Is Nothing Then Set ExApp = Application
With ExApp                  '<~ we are working on ExApp object
  .DisplayAlerts = bHolder  '<~ ung pop-up messages(Eg. before iClose ung workbook, before mag-merge ng cell na parehong my value)
  .ScreenUpdating = bHolder '<~ eto ung pag-blink ng monitor kpag merong ng ra-run na code.
  .EnableEvents = bHolder   '<~ lahat ng events na mati-trigger nung codes. Excellent para iwas unlimitted looping.
  .Calculation = IIf(isOn, xlCalculationManual, xlCalculationAutomatic) '<~ manual = hnd mag-a-update ung mga cell with formula. auto = update sila ng update
  .Calculate                '<~ Force calculation. regardless kung iOn/Off ung pag-optimize ng codes.
    If .VERSION > 12 Then .PrintCommunication = bHolder '<~ print preview before kapag ng CTRL+P
End With                    '<~ exit working with ExApp Object.
On Error GoTo 0             '<~ resume raising of errors.
End Sub

Comment: dini-disable nya ung mga setting ng excel na nagra-run/nati-trigger
once na nag-simula na ung code nyo.



How to use:

Ipaste lang sa regular code module. then ready to use na sya.
Kung gusto i-On ung pag-optimize ng code. use

OPTIMIZE_VBA True

Note: since subroutine ito. no need na ung pharenthesis after nung vba.
pero pede din sa ganitong syntax.

call OPTIMIZE_VBA(True)

Kung gusto i-Off ung pag-optimize ng code. use

OPTIMIZE_VBA False

Kung gagamitin sa existing na code nyo. Example:

Public Sub DoSomething1()
Dim lLoop As Long

OPTIMIZE_VBA True           '<~ tawagin ung pampabilis ng codes.
For lLoop = 1 To 100                '<~ loop 1 to 100
  Sheet1.Cells(lLoop, 1) = lLoop    '<~ ipasa sa sheet1
Next                                '<~ next
OPTIMIZE_VBA False          '<~ ibalik sa normal ung mga value.
End Sub

pede din gamitin kapag ibang instance ng excel ang
gustong i-optimize. Example:

Public Sub DoSomething2()
Dim ExAppDoSum2 As Excel.Application    '<~ variable na mg-ho-hold ng Excel Application
Dim ExWbkDoSum2 As Excel.Workbook       '<~ variable na mg-ho-hold ng Excel Workbook
Dim ExWshDoSum2 As Excel.Worksheet      '<~ variable na mg-ho-hold ng Excel Worksheet
Dim lLoopDoSum2 As Long

Set ExAppDoSum2 = New Excel.Application         '<~ creating another instance of excel. eto ung iDidisable naten.(wala pang workbook)
Set ExWbkDoSum2 = ExAppDoSum2.Workbooks.Add     '<~ creating of workbook. dahil wla pang workbook kahit meron ng excelapp.
Set ExWshDoSum2 = ExWbkDoSum2.Worksheets(1)     '<~ kunin naten ung pinaka-unang worksheet sa loob ng workbook

OPTIMIZE_VBA True, ExAppDoSum2              '<~ tawagin ung pampabilis ng codes.
    For lLoop = 1 To 100                    '<~ loop 1 to 100
      ExWshDoSum2.Cells(lLoop, 1) = lLoop   '<~ ipasa sa sheet1
    Next                                    '<~ next
OPTIMIZE_VBA False, ExAppDoSum2             '<~ ibalik sa normal ung mga value.

End Sub

Disclaimer:
#1. hindi ko po sinisugradong mapapabilis netong code lahat codes nyo. Nag-re-rely pa din ang performance ng code nyo kung paano nyo i-handle ang mga objects/variables nyo.
#2. downside ng approach na to ay kung naka-base ung mga codes nyo sa event ng excel (eg: on_change event, on_selectionChange event) ay hindi mag-ti-trigger kapag naka ON ang OPTIMIZE_VBA.

Goodluck!

 

[dw4elg]

Re: MS excel reportings, presentations, and vba helping thre

sir gusto ko sanang gawin to https://www.youtube.com/watch?v=YIhpnjbcP6c kaso mahirap sundan.... pwede bang patulong

 

[romcel11]

Re: MS excel reportings, presentations, and vba helping thre

sir gusto ko sanang gawin to https://www.youtube.com/watch?v=YIhpnjbcP6c kaso mahirap sundan.... pwede bang patulong

ano po ibg mong sbhing gawin?

A. Gagamitin mo tong form na to?

Ans: merong donwloadable form dun sa details ng video. pero inatach ko naden.

Click Here 1
Click Here 2

B. Gagawa ng sariling ganito?

Ans: eto ung mga code na ginamit nya.


para sa pagcheck ng pangalan:

Sub Button1_Click()
    y = 5
    Do
        s = UCase(Trim(Cells(y, 2)))
        If s = "" Then Exit Do
        p = InStr(1, s, ",")
        Ln = Mid(s, 1, p - 1)
        fn = Trim(Mid(s, p + 1))
        If Mid(fn, Len(fn), 1) = "-" Then
            fn = Trim(Mid(fn, 1, Len(fn) - 1))
        Else
            If Mid(fn, Len(fn) - 2, 3) = " JR" Then
                Ln = Ln & " JR"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            ElseIf Mid(fn, Len(fn) - 2, 3) = " SR" Then
                Ln = Ln & " SR"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            ElseIf Mid(fn, Len(fn) - 2, 3) = " II" Then
                Ln = Ln & " II"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            ElseIf Mid(fn, Len(fn) - 2, 3) = " IV" Then
                Ln = Ln & " II"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            End If
            p = InStrRev(fn, " ")
            p1 = InStrRev(fn, " ", p - 1)
            
            If p1 > 0 Then
                mn = Mid(fn, p1, p - p1 + 1)
                Select Case mn
                    Case " DEL ", " DE ", " DELA ", " STA ", " SANTA ": fn = Mid(fn, 1, p1 + 2)
                End Select
            End If
            
            p = InStrRev(fn, " ")
            fn = Mid(fn, 1, p + 1) & "."
            
        End If
        s = fn & " " & Ln
        Cells(y, 3) = s
        y = y + 1
    Loop While s <> ""
End Sub

para sa pag print out:

Sub printall()
    MsgBox "Creator: Giovanne Palma" & vbCrLf & vbCrLf & "Please suport ...." & vbCrLf & "Watch, Share, Like, Subscribe", vbCritical
    Sheet4.Activate
    Set wl = Worksheets("List")
    y = 5
    Do
        lrn = wl.Cells(y, 1)
        nm = UCase(wl.Cells(y, 2))
        If nm <> "" Then
            Sheet4.Shapes.Range(Array("TextBox 25")).Select
            Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = nm
            Sheet4.Shapes.Range(Array("TextBox 26")).Select
            Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = " " & lrn
            If MsgBox("Print (Y/N): " & nm & "  " & lrn, vbYesNo) = vbYes Then
                Sheet4.PrintOut
            Else
                Exit Do
            End If
        End If
        y = y + 1
    Loop While nm <> ""
    MsgBox "Printing finished..."
End Sub

Note: kung gagamitin mo po ito sa mga codes mo. i-edit mo lang ung mga pangalan ng shapes.

 

[dw4elg]

Re: MS excel reportings, presentations, and vba helping thre

ano po ibg mong sbhing gawin?

A. Gagamitin mo tong form na to?

Ans: merong donwloadable form dun sa details ng video. pero inatach ko naden.

Click Here 1
Click Here 2

B. Gagawa ng sariling ganito?

Ans: eto ung mga code na ginamit nya.


para sa pagcheck ng pangalan:

Sub Button1_Click()
    y = 5
    Do
        s = UCase(Trim(Cells(y, 2)))
        If s = "" Then Exit Do
        p = InStr(1, s, ",")
        Ln = Mid(s, 1, p - 1)
        fn = Trim(Mid(s, p + 1))
        If Mid(fn, Len(fn), 1) = "-" Then
            fn = Trim(Mid(fn, 1, Len(fn) - 1))
        Else
            If Mid(fn, Len(fn) - 2, 3) = " JR" Then
                Ln = Ln & " JR"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            ElseIf Mid(fn, Len(fn) - 2, 3) = " SR" Then
                Ln = Ln & " SR"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            ElseIf Mid(fn, Len(fn) - 2, 3) = " II" Then
                Ln = Ln & " II"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            ElseIf Mid(fn, Len(fn) - 2, 3) = " IV" Then
                Ln = Ln & " II"
                fn = Trim(Mid(fn, 1, Len(fn) - 2))
            End If
            p = InStrRev(fn, " ")
            p1 = InStrRev(fn, " ", p - 1)
            
            If p1 > 0 Then
                mn = Mid(fn, p1, p - p1 + 1)
                Select Case mn
                    Case " DEL ", " DE ", " DELA ", " STA ", " SANTA ": fn = Mid(fn, 1, p1 + 2)
                End Select
            End If
            
            p = InStrRev(fn, " ")
            fn = Mid(fn, 1, p + 1) & "."
            
        End If
        s = fn & " " & Ln
        Cells(y, 3) = s
        y = y + 1
    Loop While s <> ""
End Sub

para sa pag print out:

Sub printall()
    MsgBox "Creator: Giovanne Palma" & vbCrLf & vbCrLf & "Please suport ...." & vbCrLf & "Watch, Share, Like, Subscribe", vbCritical
    Sheet4.Activate
    Set wl = Worksheets("List")
    y = 5
    Do
        lrn = wl.Cells(y, 1)
        nm = UCase(wl.Cells(y, 2))
        If nm <> "" Then
            Sheet4.Shapes.Range(Array("TextBox 25")).Select
            Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = nm
            Sheet4.Shapes.Range(Array("TextBox 26")).Select
            Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = " " & lrn
            If MsgBox("Print (Y/N): " & nm & "  " & lrn, vbYesNo) = vbYes Then
                Sheet4.PrintOut
            Else
                Exit Do
            End If
        End If
        y = y + 1
    Loop While nm <> ""
    MsgBox "Printing finished..."
End Sub

Note: kung gagamitin mo po ito sa mga codes mo. i-edit mo lang ung mga pangalan ng shapes.

thanks much sir.... aaralin ko muna kung pano gamitin ang code sa excel.... interested but baguhan... xencia na

 

[romcel11]

Re: MS excel reportings, presentations, and vba helping thre

Share ko lang sana makatulong.
Nangyari na ba na kailangan mong iformat ang ilan/mga words sa isang cell?
Eto ung code na ginagamit ko para i-Bold or i-Underline ung mga words na yon.

sub routine ito, na may mga arguements so hindi sya ma-ra-run using F5.
tawagin nyo n lang ito using immediate window, or create ng new SubRoutine para
i-pasa sa sub na ito ung mga arguements.

SEARCH_AND_FORMAT

Public Sub SearchAndFormat(ByRef rngRange As Range, ByRef strWhat As String, Optional ByVal boolBold As Boolean = False, _
Optional ByVal boolUndr As Boolean = False, Optional ByVal boolFormatOnce As Boolean = False, Optional ByVal boolFormatAfterNthMatch As Boolean = False, _
Optional ByVal intNthMatch As Integer = 1)
Dim lngLoop As Long, strValue As String, intNthCounter As Integer

strValue = rngRange.Value           '<~ get the string from the range
If Len(Trim(strValue)) < 1 Then     '<~ check if the string is not blank.
  MsgBox "Unable to proceed. Cell is empty", vbInformation, "(!)Request denied."
  Exit Sub                          '<~ exits this sub if it is blank.
End If

If Len(Trim(strValue)) < Len(Trim(strWhat)) Then        '<~ checks if the strign length is enough
  MsgBox "Unable to proceed. Search string is too long.", vbInformation, "(!)Request denied."
  Exit Sub                                              '<~ exits this sub if search string is longer.
End If

For lngLoop = 1 To (Len(strValue) - Len(strWhat)) + 1   '<~ Loop through the string. test each string with the same length of strWhat.
  If StrComp(Mid(strValue, lngLoop, Len(strWhat)), strWhat, vbTextCompare) = 0 Then '<~ compare strwhat for every set of characters with the same length in strValue.
    intNthCounter = intNthCounter + 1                   '<~ increment for every match found
    If boolFormatAfterNthMatch And intNthCounter <= intNthMatch Then GoTo NxtItm  '<~ skip formatting if number of matches not correct.
    
    With rngRange.Characters(lngLoop, Len(strWhat))     '<~ if there is a match. We are working with that string.
      If boolBold Then .Font.Bold = True                '<~ Apply bold format, if its set into true.
      If boolUndr Then .Font.Underline = 2              '<~ apply underline format, if tis set to true.
      If boolFormatOnce Then Exit Sub                   '<~ check if this needs to be applied once.
    End With                                            '<~ end of working with that string.
  End If
NxtItm:
Next

MsgBox "Request done." & vbCrLf & _
"Found " & intNthCounter & " matches in cell " & rngRange.Address(0, 0) & "." & vbCrLf, _
vbInformation, "(!) Request done."

End Sub

Comment: Ang idea dito, kunin ung value nung cell, then i-compare dun sa string na hinahanap nyo.
maglo-loop to sa bawat combination of letters dun sa value ng cell na kasing haba ng string na hinahanap.
Example:
[A1]Cell Value = "The quick brown fox jumps over the lazy dog"
String = "brown"

001=is "The Q" = "brown"? = no
002=is "he Qu" = "brown"? = no
003=is "e Qui" = "brown"? = no
004=is " Quic" = "brown"? = no
005=is "Quick" = "brown"? = no
006=is "uick " = "brown"? = no
...
...
nth=is "brown" = "brown"? = yes, then make it bold or underline

How to use:
Ipaste lang sa regular code module. then ready to use na sya.




Samples:

Para ibold lahat ng match:

Sub FormatSomethingBoldAll()
'<~ this will set every "Apple" found in that cell to BOLD.
SearchAndFormat ThisWorkbook.Worksheets("Sheet1").Range("A1"), "Apple", True
End Sub

Para iUnderline lahat ng match:

Sub FormatSomethingUnderlineAll()
'<~ this will set every "Apple" found in that cell to UNDERLINED.
SearchAndFormat ThisWorkbook.Worksheets("Sheet1").Range("A1"), "Apple", False, True
End Sub

Para iBold at iUnderline lahat ng match:

Sub FormatBoldAndUnderline()
'<~ this will set every "Apple" found in that cell to BOLD AND UNDERLINED.
SearchAndFormat ThisWorkbook.Worksheets("Sheet1").Range("A1"), "Apple", True, True
End Sub

Para iBold ang unang match:

Sub BoldOnce()
'<~ this will set first "Apple" found in that cell to BOLD.
SearchAndFormat ThisWorkbook.Worksheets("Sheet1").Range("A1"), "Apple", True, , True
End Sub

Para iBold lahat ng match after 2nd match:

Sub BoldAfter2nd()
'<~ this will set all "Apple" found after the SECOND match in that cell to BOLD.
SearchAndFormat ThisWorkbook.Worksheets("Sheet1").Range("A1"), "Apple", True, , , True, 2
End Sub

Para iBold ang unang match after 2nd Match:

Sub BoldOnceAfter2nd()
'<~ this will set the only "Apple" found after the SECOND match in that cell to BOLD.
SearchAndFormat ThisWorkbook.Worksheets("Sheet1").Range("A1"), "Apple", True, , True, True, 2
End Sub

Hope this helps!

 

[Yamster17]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Hi Guys,

papatulong po sana ako sa inyo o papaturo kung paano gumawa nang mga excel data for Quality tools , such as control chart or mga files to have a root cause analysis. Thanks in advance

 

[LightHole24]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Mga master, patulong naman po ako sa problem ko. Sana patulong

Gusto ko po sanang mangyari jan sa ginagawa kong yan ay ganito... Gusto ko po na lahat ng cell from CELL C4 to CELL F25 ay ma-affect EXCEPT dun sa cell na walang value o number... Gusto ko po sana ay magta-type ako ng number tapos ay mag-subtract siya automatic sa taas niyang cell. May nakuha po akong code pero hindi ko alam pano i adjust eh. Pero parang ganun sana yung gusto kong mangyari, ibang cell nga lang yung affected nung code. Nasa baba yung code

Example gaya nung nasa picture...

Dun sa A field, noong April 4 ay naglagay ako ng 19. The next day April 5 naglagay naman ako ng 258.75. Gusto ko po na dapat sana ay nung nilagay ko yung 258.75, dapat matic na nag subtract yung value ni CELL C5 kay CELL C4 at imbes na ang ma-display kay C5 ay 258.75, dapat ay 239.75 nalang.

Sa CELL D5 naman ay naglagay ako ng 27. Then noong next day, sa D6 naglagay naman ako ng 217. Gusto ko po na dapat ang maging value ni D6 ay 190, kumbaga automatic na nag subtract agad si D6 value kay D5 value at ang result nun ay ni-display kay D6 agad...

Para naman dun sa D,E,at F row 4 CELL, wala silang laman di po ba. Kung baga walang error na lalabas sa kanila...

Yung code po kasi na nakita ko sa net ay parang ganyan sana, kaya lang mali yung affected na cell eh. Jan po sa code, kapag naglagay ako ng value sa CELL F7 to F14, let say naglagay ako ng 213 sa F8 CELL, nagsu-subtract siya sa value na nilagay ko sa F8 doon sa value ng CELL B8, tapos idi-display nung CELL yung result ng F8 - B8 value. Sa sample picture ko, walang value yung B8 kaya ang lumabas ay -213...

Pero gaya ng gusto ko sanang mangyari, sana matulungan niyo po ako... Maraming salamat po!

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("F7:F14")) Is Nothing Then Exit Sub
Application.EnableEvents = False
With Target
    .Offset(, -2).Value = .Offset(, -2).Value - .Value
    .ClearContents
End With
Application.EnableEvents = True
End Sub

 

[themonyo]

Re: MS excel formula, programming, analysis, presentation and tutorials.

@LightHole24

need clarification on this part:

let's say na nagstart ka ng day 1 sa April 4...
kung nag-input ka ng value sa April 4... so, yan ang base value mo na...
kung maglagay ka ng value sa April 5, mababawasan ng automatic ang April 4
pagdating ng April 6, maglalagay ka ulit ng value sa cell, pag nagbago ang value for April 5, paano yung April 4? mababawasan din ba? hanggang kelan dapat magpalit ang values/calculation?

 

[romcel11]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Boss, eto ung sample ng gawa ko tama ba?

gumamit lang ako ng column helper.
tska ABS() function para kahit ano ang i-return na sagot dun sa subtraction. positive number padin ang i-rereturn sa output.

View attachment 341167


eto ung mga formula
View attachment 341168


good luck!

 

[LightHole24]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Boss, eto ung sample ng gawa ko tama ba?

gumamit lang ako ng column helper.
tska ABS() function para kahit ano ang i-return na sagot dun sa subtraction. positive number padin ang i-rereturn sa output.

View attachment 1252482


eto ung mga formula
View attachment 1252483


good luck!

Hi bossing! Nako marami pong salamat. Itong ginawa mong solution ay okay narin po. Salamat po sa idea

Sorry po maarte lang haha. Pero yung gusto ko po sana ay same lang po na table at cell yung mababago.. Kasi, kung titignan niyo po yung code na ni-post ko, mukang pwede naman po sana ma-achieve yung gusto ko sana mangyari haha. Kaya nga lang po ay maling cell yung nakalagay sa code at di ko maintindihan yung code kaya hirap baguhin po haha. Sorry po

- - - Updated - - -

@LightHole24

need clarification on this part:

let's say na nagstart ka ng day 1 sa April 4...
kung nag-input ka ng value sa April 4... so, yan ang base value mo na...
kung maglagay ka ng value sa April 5, mababawasan ng automatic ang April 4
pagdating ng April 6, maglalagay ka ulit ng value sa cell, pag nagbago ang value for April 5, paano yung April 4? mababawasan din ba? hanggang kelan dapat magpalit ang values/calculation?

Hi sir! Salamat po sa tulong ngayon palang

Tama po kayo dun sa part ng April 4 sir. Gaya nung nasa picture, ang base po na value ay 19. Yan po kasi yung pinaka una. Sa totoo lang po, gusto ko sana malaman kung magkano ang earnings ko kada araw sa bawat... Base po dun sa picture sir...

Dun sa A field sa may CELL C4, noong April 4 ay naglagay ako ng 19. The next day April 5 naglagay naman ako ng 258.75 sa CELL C5. Gusto ko po na dapat sana ay nung nilagay ko yung 258.75 sa CELL C5, dapat matic na nag subtract yung value ni CELL C5 kay CELL C4 at na ang ma-display kay CELL C5 ay dapat na 239.75 na lamang. Kumbaga automatic na mabubura yung nilagay kong value na 258.75 sa CELL C5 at ang idi-display ni CELL C5 automatic ay 239.75 nalang...

Sa B field o CELL D5 naman ay naglagay ako ng 27. At dahil walang value yung CELL D4, kaya yung nilagay kong 27 sa CELL D5 ang base number. Then noong next day, sa CELL D6 naglagay naman ako ng 217. At gaya kanina, gusto ko po na dapat ang maging value ni D6 ay 190 nalang kahit ang nilagay ko ay 217 kasi kumbaga automatic na nag subtract agad si CELL D6 value kay CELL D5 value at ang result nun ay ni-display kay D6 agad...

NOTE: Hindi po dapat mabawasan yung value nung C4 kasi siya yung base value. Yung nilagay ko po sa C5 ang dapat automatic na mababawasan ng value. Isu-subtract agad agad yung value ni C5 kay C4 at ang result niyan ay matic po na magdi display kay C5 parin. Kaya ang magiging base number na ni C5 ay yung result ng C5 - C4.

Sa example ko po sa picture, ang value ni C4 ay 19. Naglagay ako ng 258.75 kay C5. Ang gagawin ni C5 automatically ay... C5 value (258.75) - C4 value (19) = 239.75. Yang 239.75 ay matic na magdi display kay C5 at mawawala yung unang value na nilagay ko na 258.75. Final value ni C5 ay 239.75... Mangyayari po yang format na yan hanggang sa pinaka last na date which is gaya ng sample sa picture ay April 25. Pero in reality ay April 30 yan dapat. Sa bawat column ng C,D,E,F na ang pangalan ay (ABCD) ay mangyayari po yan... Sana po maliwanag explanation ko. Pasensiya na po

Pakisuyo po na paki download itong excel file mismo, nasa baba ang link, tapos pakilagay niyo po yung code sa worksheet niya mismo tapos ALT Q para mag close yung code editor, tapos try niyo pong maglagay ng number sa F7 to F14 para magka idea po kayo nung sinasabi ko. Mali po yang code na yan eh at gusto ko po sana ipaayos sa inyo base jan sa mga sinabi ko sa taas... Pasuyo nalang po at maraming salamat!

LINK NG EXCEL FILE

CODE NG EXCEL NA NAKITA KO PERO MALI

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("F7:F14")) Is Nothing Then Exit Sub
Application.EnableEvents = False
With Target
    .Offset(, -2).Value = .Offset(, -2).Value - .Value
    .ClearContents
End With
Application.EnableEvents = True
End Sub

 

[aubrey03]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Hi bossing! Nako marami pong salamat. Itong ginawa mong solution ay okay narin po. Salamat po sa idea

Sorry po maarte lang haha. Pero yung gusto ko po sana ay same lang po na table at cell yung mababago.. Kasi, kung titignan niyo po yung code na ni-post ko, mukang pwede naman po sana ma-achieve yung gusto ko sana mangyari haha. Kaya nga lang po ay maling cell yung nakalagay sa code at di ko maintindihan yung code kaya hirap baguhin po haha. Sorry po

- - - Updated - - -



Hi sir! Salamat po sa tulong ngayon palang

Tama po kayo dun sa part ng April 4 sir. Gaya nung nasa picture, ang base po na value ay 19. Yan po kasi yung pinaka una. Sa totoo lang po, gusto ko sana malaman kung magkano ang earnings ko kada araw sa bawat... Base po dun sa picture sir...

Dun sa A field sa may CELL C4, noong April 4 ay naglagay ako ng 19. The next day April 5 naglagay naman ako ng 258.75 sa CELL C5. Gusto ko po na dapat sana ay nung nilagay ko yung 258.75 sa CELL C5, dapat matic na nag subtract yung value ni CELL C5 kay CELL C4 at na ang ma-display kay CELL C5 ay dapat na 239.75 na lamang. Kumbaga automatic na mabubura yung nilagay kong value na 258.75 sa CELL C5 at ang idi-display ni CELL C5 automatic ay 239.75 nalang...

Sa B field o CELL D5 naman ay naglagay ako ng 27. At dahil walang value yung CELL D4, kaya yung nilagay kong 27 sa CELL D5 ang base number. Then noong next day, sa CELL D6 naglagay naman ako ng 217. At gaya kanina, gusto ko po na dapat ang maging value ni D6 ay 190 nalang kahit ang nilagay ko ay 217 kasi kumbaga automatic na nag subtract agad si CELL D6 value kay CELL D5 value at ang result nun ay ni-display kay D6 agad...

NOTE: Hindi po dapat mabawasan yung value nung C4 kasi siya yung base value. Yung nilagay ko po sa C5 ang dapat automatic na mababawasan ng value. Isu-subtract agad agad yung value ni C5 kay C4 at ang result niyan ay matic po na magdi display kay C5 parin. Kaya ang magiging base number na ni C5 ay yung result ng C5 - C4.

Sa example ko po sa picture, ang value ni C4 ay 19. Naglagay ako ng 258.75 kay C5. Ang gagawin ni C5 automatically ay... C5 value (258.75) - C4 value (19) = 239.75. Yang 239.75 ay matic na magdi display kay C5 at mawawala yung unang value na nilagay ko na 258.75. Final value ni C5 ay 239.75... Mangyayari po yang format na yan hanggang sa pinaka last na date which is gaya ng sample sa picture ay April 25. Pero in reality ay April 30 yan dapat. Sa bawat column ng C,D,E,F na ang pangalan ay (ABCD) ay mangyayari po yan... Sana po maliwanag explanation ko. Pasensiya na po

Pakisuyo po na paki download itong excel file mismo, nasa baba ang link, tapos pakilagay niyo po yung code sa worksheet niya mismo tapos ALT Q para mag close yung code editor, tapos try niyo pong maglagay ng number sa F7 to F14 para magka idea po kayo nung sinasabi ko. Mali po yang code na yan eh at gusto ko po sana ipaayos sa inyo base jan sa mga sinabi ko sa taas... Pasuyo nalang po at maraming salamat!

LINK NG EXCEL FILE

CODE NG EXCEL NA NAKITA KO PERO MALI

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("F7:F14")) Is Nothing Then Exit Sub
Application.EnableEvents = False
With Target
    .Offset(, -2).Value = .Offset(, -2).Value - .Value
    .ClearContents
End With
Application.EnableEvents = True
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("C5:F25")) Is Nothing Then Exit Sub
Application.EnableEvents = False
With Target
.Value = .Value - .Offset(-1, 0).Value

End With
Application.EnableEvents = True
End Sub

 

[romcel11]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Hi bossing! Nako marami pong salamat. Itong ginawa mong solution ay okay narin po. Salamat po sa idea

Sorry po maarte lang haha. Pero yung gusto ko po sana ay same lang po na table at cell yung mababago.. Kasi, kung titignan niyo po yung code na ni-post ko, mukang pwede naman po sana ma-achieve yung gusto ko sana mangyari haha. Kaya nga lang po ay maling cell yung nakalagay sa code at di ko maintindihan yung code kaya hirap baguhin po haha. Sorry po

No problem! Madalas ganyan din ako.
try mo po tong ni-revise kong code.
palitan mo po ung code na gngmit mo ngayon. paste mo yan dun

Private Sub Worksheet_Change(ByVal Target As Range)
Dim rTarget As Range        '<~ range will hold target. old habits never die.
Dim dblValHolder As Double  '<~ will hold the value of rtarget.

'<~ to ensure na ung nagbagong cell ay within the table
If Intersect(Target, Range("C5:F25")) Is Nothing Then Exit Sub

Set rTarget = Target    '<~ pass target to the declared variable

'<~ to ensure na isang cell lang ung nagbago.
'<~ incase na ng delete ka ng multiple cell within the table,
'<~ then exit sub na.
If rTarget.Cells.Count > 1 Then Exit Sub

Application.EnableEvents = False            '<~ disable naten events. bka mgtrigger ung ibang cell events.
With rTarget
  '<~i-hold natin ung value na ininput mo
  If Not IsNumeric(.Value) Then Exit Sub    '<~ exit sub tayo kpag text ang ininput.
  If Not IsNumeric(.Offset(-1, 0).Value) Then Exit Sub '<~ ganon din kung hnd number ung sa taas.
  dblValHolder = CDbl(.Value)               '<~ pass naten sa variable
  .ClearContents                            '<~ remove naten ung value ng cell na ngbago.
  .Value = Abs(.Offset(-1, 0).Value - dblValHolder) '<~ do the math.
End With
Application.EnableEvents = True             '<~ enable naten ulit.

End Sub

EDIT:
Yung i-rereturn na number ng code na to ay PURO possitive.
kung hindi ito ok. remove Abs() in .Value = Abs(.Offset(-1, 0).Value - dblValHolder)

ang magiging output ay....

.Value = .Offset(-1, 0).Value - dblValHolder

 

[LightHole24]

Re: MS excel formula, programming, analysis, presentation and tutorials.

No problem! Madalas ganyan din ako.
try mo po tong ni-revise kong code.
palitan mo po ung code na gngmit mo ngayon. paste mo yan dun

Private Sub Worksheet_Change(ByVal Target As Range)
Dim rTarget As Range        '<~ range will hold target. old habits never die.
Dim dblValHolder As Double  '<~ will hold the value of rtarget.

'<~ to ensure na ung nagbagong cell ay within the table
If Intersect(Target, Range("C5:F25")) Is Nothing Then Exit Sub

Set rTarget = Target    '<~ pass target to the declared variable

'<~ to ensure na isang cell lang ung nagbago.
'<~ incase na ng delete ka ng multiple cell within the table,
'<~ then exit sub na.
If rTarget.Cells.Count > 1 Then Exit Sub

Application.EnableEvents = False            '<~ disable naten events. bka mgtrigger ung ibang cell events.
With rTarget
  '<~i-hold natin ung value na ininput mo
  If Not IsNumeric(.Value) Then Exit Sub    '<~ exit sub tayo kpag text ang ininput.
  If Not IsNumeric(.Offset(-1, 0).Value) Then Exit Sub '<~ ganon din kung hnd number ung sa taas.
  dblValHolder = CDbl(.Value)               '<~ pass naten sa variable
  .ClearContents                            '<~ remove naten ung value ng cell na ngbago.
  .Value = Abs(.Offset(-1, 0).Value - dblValHolder) '<~ do the math.
End With
Application.EnableEvents = True             '<~ enable naten ulit.

End Sub

EDIT:
Yung i-rereturn na number ng code na to ay PURO possitive.
kung hindi ito ok. remove Abs() in .Value = Abs(.Offset(-1, 0).Value - dblValHolder)

ang magiging output ay....

.Value = .Offset(-1, 0).Value - dblValHolder

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("C5:F25")) Is Nothing Then Exit Sub
Application.EnableEvents = False
With Target
.Value = .Value - .Offset(-1, 0).Value

End With
Application.EnableEvents = True
End Sub

Wow ayos. Pareho pong working yung code niyo! Working na working code niyo jan sa scenario na gusto ko mangyari. Salamat po

Tanong ko lang po, ang nangyari kasi ngayon ay let say naglagay ako ng 19 sa CELL C4 tapos 258.75 sa CELL C5. So nag auto subtract na si CELL C5 kay C5 at ang nag display na value kay C5 ay yung result ng subtraction. Ayus na ayus narin po sana yun, kaso pasensiya po uli kasi maarte lang talaga si dodong

Kaya ba na yung unang value na nilagay ko sa CELL C5 which is 258.75, ay magiging comment siya nung final value ni C5 na 239.75? Kumbaga kapag ni-hover ko yung CELL C5 na may laman nung result nung automatic subtraction kay C4, may lalabas na comment na ang nakalagay sa comment ay yung original value na nilagay ko (258.75)?

Parang ganito po sa picture, nilagay ko lang po yung comment. Hehehe

Salamat po uli ng marami!

 

[aubrey03]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Wow ayos. Pareho pong working yung code niyo! Working na working code niyo jan sa scenario na gusto ko mangyari. Salamat po

Tanong ko lang po, ang nangyari kasi ngayon ay let say naglagay ako ng 19 sa CELL C4 tapos 258.75 sa CELL C5. So nag auto subtract na si CELL C5 kay C5 at ang nag display na value kay C5 ay yung result ng subtraction. Ayus na ayus narin po sana yun, kaso pasensiya po uli kasi maarte lang talaga si dodong

Kaya ba na yung unang value na nilagay ko sa CELL C5 which is 258.75, ay magiging comment siya nung final value ni C5 na 239.75? Kumbaga kapag ni-hover ko yung CELL C5 na may laman nung result nung automatic subtraction kay C4, may lalabas na comment na ang nakalagay sa comment ay yung original value na nilagay ko (258.75)?

Parang ganito po sa picture, nilagay ko lang po yung comment. Hehehe

http://www.symbianize.com/attachment.php?attachmentid=1252614&stc=1&d=1523073867

Salamat po uli ng marami!

Eto na dodong

Private Sub Worksheet_Change(ByVal Target As Range)

If Intersect(Target, Range("C5:F25")) Is Nothing Then Exit Sub
If Not IsNumeric(Target.Value) Then Exit Sub
If Not IsNumeric(Target.Offset(-1, 0).Value) Then Exit Sub

Application.EnableEvents = False
With Target
 .AddComment
 .Comment.Visible = False
 .Comment.Text Text:="Value today: " & .Value
 .Value = .Value - .Offset(-1, 0).Value
 .Comment.Text Text:=.Comment.Text & vbNewLine & "Earnings today: " & .Value
End With
Application.EnableEvents = True
End Sub

 

[LightHole24]

Re: MS excel formula, programming, analysis, presentation and tutorials.

Eto na dodong

Private Sub Worksheet_Change(ByVal Target As Range)

If Intersect(Target, Range("C5:F25")) Is Nothing Then Exit Sub
If Not IsNumeric(Target.Value) Then Exit Sub
If Not IsNumeric(Target.Offset(-1, 0).Value) Then Exit Sub

Application.EnableEvents = False
With Target
 .AddComment
 .Comment.Visible = False
 .Comment.Text Text:="Value today: " & .Value
 .Value = .Value - .Offset(-1, 0).Value
 .Comment.Text Text:=.Comment.Text & vbNewLine & "Earnings today: " & .Value
End With
Application.EnableEvents = True
End Sub

Master maraming salamat sa code mo. Pinagbasihan ko code niyong dalawa ni master romcel tapos nagtingin tingin ako sa google/youtube kung pano mag add ng comment. Sa wakas nakuha ko rin yung gusto kong mangyari sa table ko. May comment na at nababago yung comment kapag binago ko yung value ng cell. At nawawala rin comment pag walang laman ang cell. Maraming salamat sa inyo

Ito na yung code ko ngayon

Private Sub Worksheet_Change(ByVal Target As Range)
Dim rTarget As Range        '<~ range will hold target. old habits never die.
Dim dblValHolder As Double  '<~ will hold the value of rtarget.
Dim dblCurrentValue As Double   '<~ will hold the current value
Dim ws As Worksheet     '<~ di ko alam para san to, ginaya ko lang haha

'<~ to ensure na ung nagbagong cell ay within the table
If Intersect(Target, Range("C5:F30")) Is Nothing Then Exit Sub

Set rTarget = Target    '<~ pass target to the declared variable

'<~ to ensure na isang cell lang ung nagbago.
'<~ incase na ng delete ka ng multiple cell within the table,
'<~ then exit sub na.
If rTarget.Cells.Count > 1 Then Exit Sub

Application.EnableEvents = False            '<~ disable naten events. bka mgtrigger ung ibang cell events.
With rTarget
  '<~i-hold natin ung value na ininput mo
  If Not IsNumeric(.Value) Then Exit Sub    '<~ exit sub tayo kpag text ang ininput.
  If Not IsNumeric(.Offset(-1, 0).Value) Then Exit Sub '<~ ganon din kung hnd number ung sa taas.
  dblValHolder = CDbl(.Value)               '<~ pass naten sa variable
  dblCurrentValue = dblValHolder            '<~ copy the value of ValHolder to CurrentValue
  
    If dblValHolder = 0 Or rTarget.Value = "" Then '<~ naglagay ako validation kung may value ba yung cell or empty
        rTarget.ClearContents
    Else
        rTarget.ClearContents                            '<~ remove naten ung value ng cell na ngbago.
        .Value = Abs(.Offset(-1, 0).Value - dblValHolder) '<~ do the math.
    End If
End With

For Each rTarget In Target
    If rTarget.Comment Is Nothing And rTarget.Value = "" Then   '<~ kung walang laman ang cell, wala ring comment
        rTarget.ClearContents
        rTarget.Comment.Delete
    
    ElseIf rTarget.Comment Is Nothing And rTarget.Value <> "" Then  '<~ kung may laman ang cell, mayroon ring comment
        With rTarget.AddComment
            .Visible = False
            .Text "Current Value Today: " & dblCurrentValue & vbNewLine & "Current Earnings Today: " & rTarget.Value
        End With
            
    ElseIf Not rTarget.Comment Is Nothing And rTarget.Value <> "" Then      '<~ kapag nag edit ako ng value ng cell
        With rTarget.Comment
            .Visible = False
            .Text "Current Value Today: " & dblCurrentValue & vbNewLine & "Current Earnings Today: " & rTarget.Value
        End With
    
    ElseIf Not rTarget.Comment Is Nothing And rTarget.Value = "" Then       '<~ kung may laman ang cell, pero nag delete ako ng value sa cell, wala ring comment
        rTarget.ClearContents
        rTarget.Comment.Delete
    
        'rTarget.Comment.Text Application.UserName & "-" & rTarget.Value & vbNewLine & rTarget.Comment.Text
    End If
Next

'With Target
' .AddComment
' .Comment.Visible = False
' .Comment.Text Text:="Value today: " & .Value
' .Value = .Value - .Offset(-1, 0).Value
' .Comment.Text Text:=.Comment.Text & vbNewLine & "Earnings today: " & .Value
'End With

Application.EnableEvents = True             '<~ enable naten ulit.

End Sub

 

[geyfud]

Re: MS excel formula, programming, analysis, presentation and tutorials.

marami akong matutunan dito.. pa bm thanks